Zeoslib Portal

Code: Select all

{**
  Performs an internal refreshing.
}

procedure TZAbstractRODataset.InternalRefresh;
var
   RowNo: Integer;
   Found: Boolean;
   KeyFields: string;
   Temp: TZVariantDynArray;
   KeyValues: Variant;
   FieldRefs: TObjectDynArray;
   OnlyDataFields: Boolean;
begin
   FieldRefs := nil;
   if Active then
   begin
      if CurrentRow > 0 then
      begin
         RowNo := Integer(CurrentRows[CurrentRow - 1]);
         if ResultSet.GetRow <> RowNo then
            ResultSet.MoveAbsolute(RowNo);

         if Properties.Values['KeyFields'] <> '' then
            KeyFields := Properties.Values['KeyFields']
         else
            KeyFields := DefineKeyFields(Fields);
         FieldRefs := DefineFields(Self, KeyFields, OnlyDataFields);
         SetLength(Temp, Length(FieldRefs));
         RetrieveDataFieldsFromResultSet(FieldRefs, ResultSet, Temp);
         if Length(FieldRefs) = 1 then
            KeyValues := EncodeVariant(Temp[0])
         else KeyValues := EncodeVariantArray(Temp);
      end
      else
      begin
         KeyFields := '';
         KeyValues := Unassigned;
      end;

      DisableControls;
      try
         try
            FRefreshInProgress := True;
            InternalClose;
            InternalOpen;
         finally
            FRefreshInProgress := False;
         end;

         DoBeforeScroll;
         if KeyFields <> '' then
            Found := Locate(KeyFields, KeyValues, [])
         else Found := False;
      finally
         EnableControls;
      end;

      if not Found then
      begin
         DoBeforeScroll;
         DoAfterScroll;
      end;
   end;
end;